La fonction GOOGLEFINANCE permet de récupérer automatiquement des données boursières sur des actions à partir des services de Google Finance.

Utilisation

=GOOGLEFINANCE("EPA:TTE")
=GOOGLEFINANCE("NASDAQ:AAPL";"price";AUJOURDHUI()-30;AUJOURDHUI())

Syntaxe

=GOOGLEFINANCE(titre; [attribut]; [dateDébut]; [dateFin]; [interval])
  • titre : le ticker (le code) de l’action
  • attribut (Optionnel) : le type de donnée à récupérer. Les plus courants :
    • price : cours de l’action en temps réel
    • priceopen : cours de l’action à l’ouverture des marchés
    • high : cours le plus haut sur la journée
    • low : cours le plus bas sur la journée
    • volume : volume échangé sur la journée
    • marketcap : capitalisation totale du titre
    • volumeavg : volume d’échange moyen quotidien
    • shares : nombre de titres en circulation
    • currency : devise utilisée pour valoriser le titre
  • dateDébut (Optionnel) : date de début
  • dateFin (Optionnel) : date de fin
  • interval (Optionnel) : interval de chaque valeur ("DAILY" ou "WEEKLY" )
    • Par défaut : Daily

Trouver le ticker d’une action

Pour trouver les tickers (les codes) des actions, allez sur google.com/finance Recherchez l’action que vous souhaitez, et copiez le code dans la barre de recherche. Il se trouve sous la forme marché:action par exemple EPA:CA pour l’action Carrefour. Attention à bien enlever l’espace après les : .

Démonstration de recheche dans Google Finance pour trouver le ticker d'une action.

Usage

1. Récupérer le prix d’une action en temps réel

Je veux récupérer le prix d’une action Apple en temps réel.

Extrait d’un tableau Google Sheets utilisant la formule =GOOGLEFINANCE("NASDAQ:AAPL", "price") pour récupérer le cours de l’action Apple, affiché à 203,92 USD.
=GOOGLEFINANCE("NASDAQ:AAPL"; "price")

Cette formule affiche le prix de l’action Apple en temps réel (différé de 20 min max). Il est intéressant de coupler cette info avec la devise utilisée, en utilisant l’attribut currency.

Feuille Google Sheets affichant la devise "USD" pour le titre Apple grâce à la formule =GOOGLEFINANCE("NASDAQ:AAPL", "currency")
=GOOGLEFINANCE("NASDAQ:AAPL"; "currency")

Grâce à ces deux infos, on sait que l’action Apple a actuellement un cours de 203.92$.

2. Récupérer l’historique des performances d’une action

Je veux récupérer l’historique des actions TotalEnergies sur 365 jours glisants.

Tableau Google Sheets affichant l’historique du prix de l’action TotalEnergies (EPA:TTE) sur l'année, grâce à la formule =GOOGLEFINANCE("EPA:TTE", "price", AUJOURDHUI()-365, AUJOURDHUI())
=GOOGLEFINANCE("EPA:TTE";"price";AUJOURDHUI()-365;AUJOURDHUI())

Cette formule affiche un tableau des prix de clôture sur un an glissant de l’action TotalEnergies. Un tableau avec les entêtes Date et Close est automatiquement créé, avec les valeurs en dessous.

3. Créer un dashboard d’actions

Je veux créer un dashboard pour suivre les actions de mon portefeuille.

Tableau comparatif dans Google Sheets listant les sociétés TotalEnergies, Carrefour, Air Liquide et Apple avec leur ticker, devise, prix d’ouverture, valeur actuelle, plus bas et plus haut du jour, et un graphique miniature de l’évolution sur un an

En combinant plusieurs attributs, il est possible de se créer un dashboard complet. Dans l’exemple ci-dessus, j’ai utilisé les formules suivantes pour :

Afficher la devise de l’action

=GOOGLEFINANCE(B2;"currency")

Afficher le cours d’ouverture de l’action

=GOOGLEFINANCE($B2;"priceopen")

Afficher le cours actuel de l’action

=GOOGLEFINANCE($B2;"price")

Afficher la valeur la plus basse atteinte aujourd’hui

=GOOGLEFINANCE($B2;"low")

Afficher la valeur la plus haute atteinte aujourd’hui

=GOOGLEFINANCE($B2;"high")

Afficher le graphique de l’évolution sur 1 an de l’action grâce à la fonction SPARKLINE qui affiche un graphique à partir d’un tableau de données

=SPARKLINE(GOOGLEFINANCE($B2;"price";AUJOURDHUI()-365;AUJOURDHUI()))

Voir plus 

Documentation Google : GOOGLEFINANCE – Support Google

Catégorisé dans :

Formules, Google,